;//*****************************************************   
;//Copyright (c) 2025, 苏州华芯微电子股份有限公司
;//All rights reserved                                 
;//
;//文件名称: HS16F1886-TC0 
;//摘    要: HS16F1886-TC0功能演示
;//  	    TC0周期定时溢出中断演示
;//
;//当前版本: 1.0                                      
;//作    者: 华芯微MCU组
;//完成日期: 2025.06.20
;//*****************************************************   

;***********************************************************
;files include
#include "HS16P1886.inc"
;***********************************************************
;用户IO定义
#define		OUT	PORTB,1
#define		IN	PORTB,0
DELAY_OUTSIDE	EQU		042H
DELAY_INSIDE	EQU		043H

;***********************************************************
;user general reg define
DELAY_US		EQU		40H
DELAY_MS_CNT		EQU		41H



STATUS_BUF	EQU		07EH;中断保护寄存器必须放 0x70-0x7F不要动！！！
ACC_BUF		EQU		07FH;中断保护寄存器必须放 0x70-0x7F不要动！！！
;***********************************************************
;/函数入口地址
	ORG			00H
	NOP
	NOP
	GOTO		MAIN_SETUP
	
;/中断入口地址04H
	ORG	04H
	GOTO	INT_PRO
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	BCR	STATUS,5    ;切换到BANK0
	BCR	STATUS,6
;	检查TC0溢出中断
	BTRSS	FTC0IF
	GOTO	TC0_INT_END
	BCR		FTC0IF
	MOVIA	128
	MOVAR	TC0L		;TC0 无重装载功能，要改变周期需要在中断里手动改变 TC0L的值
	;理论上128us翻转一次，实际多1-2个TC0时钟，并非内部RC误差导致，内部HIRC误差在2.5%
	MOVIA	002H
	XORAR	PORTB,1		;翻转PB1
TC0_INT_END:
;====================================================

	
INT_BACK:	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS		;恢复STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0	;恢复ACC
	RETFIE
;//中断代码结束   INTEN
	

;==========================================================================
;主程序开始
MAIN_SETUP:
	CALL	SYS_CPIO_INIT	;系统寄存器和GPIO配置
	CALL	CLR_ALL_RAM  	;清所有ram
	CALL	WDT_Init     	;看门狗初始化
	CALL	tc0_tim_init	;tc0初始化
	BSR		GIE				;开总中断
MAIN_LOOP:
	CLRWDT	  				;清看门狗
	BCR		STATUS,5	;保证转到bank0/2再操作PORTB
	BCR		STATUS,6
	MOVIA	004H
	XORAR	PORTB,1		;翻转PB1
	MOVIA	50
	CALL	DELAY
	GOTO	MAIN_LOOP		;主函数循环

;***********************************************************
;函数名：SYS_CPIO_INIT
;注意寄存器所在 bank 区域
;***********************************************************
SYS_CPIO_INIT:
	BCR		STATUS,5	;保证转到bank0/2再操作PORTB
	BCR		STATUS,6
	MOVIA	000H		;0000 0000
	MOVAR	PORTB
	BSR		STATUS,5	;转到bank1
	BCR		STATUS,6
	
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN		
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	01H			;--00 0001 :PORTB输入输出配置寄存器 (0-OUT;1-IN) 
	MOVAR	TRISB		;0-OUT, 1-IN
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB变化中断唤醒寄存器 (1-EN;0=DIS)
	MOVAR	WUCON		;0-DIS, 1-EN
		;PBIC0(BANK1)(PORB驱动低电平控制寄存器)
		MOVIA	00H			;--00 0000 :
		MOVAR	PBIC0		;0-DIS, 1-EN
        
		;XTCON(BANK1)(外振模式控制寄存器)
		;MOVIA	00H			;--00 0000 :
		;MOVAR	XTCON		;
				;bit5: XTSEN1：外振软件增强使能位 1（与上位机配置共同控制） 0-en;1-dis
				;bit4: XTSEN0：外振软件增强使能位 0（与上位机配置共同控制） 0-en;1-dis
				;bit3: XTEN：外振软件使能位（与上位机配置共同控制）		 0-en;1-dis
				;bit2: XT_TC0S：TC0 低速时钟选择		0-内部低速时钟；1-外部32.768K 
				;bit1: XT_LRCS：低速模式系统时钟选择	0-dis ; 1-EN
				;bit0:	XT_MONE：外振监测使能
	
	BCR		STATUS,5	;转到bank0
	BCR		STATUS,6	
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;---- --11 :bit3:0 PORTA3:0下拉寄存器; bit7:4 PORTB3:0下拉寄存器;1-DIS;0-EN
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB开漏寄存器 (1-EN;0-DIS)
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FEH		;--11 1110 :PORTB上拉寄存器 (1-DIS;0-EN)
	MOVAR	PHCON		;0-EN, 1-DIS
	
		;DRVC0(BANK0)(PB0 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC0		;0-EN, 1-DIS
		
		;DRVC1(BANK0)(PB1 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC1		;0-EN, 1-DIS
		
		;DRVC2(BANK0)(PB2 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC2		;0-EN, 1-DIS
	
	RETURN
	
;***********************************************************
;函数名：BANK0_RAM_CLR
;***********************************************************
CLR_ALL_RAM:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	RAM_CLR_LOOP
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时4个指令周期  Fcpu=4M时候延时1us，延时有误差
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP_US:	
	CLRWDT				;1;/清看门狗
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP_US	;2	
	RETURN				;2	
;***********************************************************
;函数名：DELAY_MS
;传参：1-255ms
;返回值：
;功能：ms级延时
;引脚：
;备注：
;***********************************************************
DELAY_MS:    
        MOVAR   DELAY_OUTSIDE 
;---------------------------
DELAY_LOOP:
        MOVIA   197
        MOVAR   DELAY_INSIDE
DELAY_LOOP_INSIDE:
        CLRWDT
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        DECRSZ  DELAY_INSIDE,R
        GOTO    DELAY_LOOP_INSIDE
        DECRSZ  DELAY_OUTSIDE,R
        GOTO    DELAY_LOOP        
DELAY_2US:       
        CLRWDT
        NOP    
        NOP
        NOP	
        NOP	
        NOP	
        RETURN  
	
;***********************************************************
;函数名：WDT_Init
;***********************************************************
/****WDT overflow reset，have no wakeup funtions****；
则看门狗复位时间仅由烧录配置：288ms；512ms；766ms；1024ms；
*/
WDT_Init:
	CLRWDT
	BSR		STATUS,5	;RP0;转到bank1
	BCR		STATUS,6
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge	
	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN					
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN			
	BCR		STATUS,5	;转到bank0
	BCR		STATUS,6
	RETURN

/**
  * @brief  tc0定时器初始化函数
  *
  * @note   TC0 无重装载功能，要改变周期需要在中断里手动改变 TC0L的值
  * @note   - 本示例使用Fpcu的4分频作为TC0时钟，也就是TC0时钟为1Mhz
  *           
  * @retval None
  */
  
tc0_tim_init:
	BCR		STATUS,5;切换到BANK0
	BCR		STATUS,6
	MOVIA	060H		;0110 00--
	MOVAR	TC0M	
		;Bit7：TC0TR:TC0 启动控制位。		
		;Bit6~Bit4：TC0S[2:0]:TC0 分频选择位
			;TC0S[2:0]		Fcpu作为时钟(TCCKS=0)		Fosc作为时钟(TCCKS=1)
			; 000				Fcpu/256					Fosc/128
			; 001				Fcpu/128                	Fosc/64
			; 010				Fcpu/64                 	Fosc/32
			; 011				Fcpu/32                 	Fosc/16
			; 100				Fcpu/16                 	Fosc/8
			; 101				Fcpu/8                  	Fosc/4
			; 110				Fcpu/4                  	Fosc/2
			; 111				Fcpu/2						Fosc/1
		;Bit3：TCCKS:TC0 时钟信号控制位 0:Fcpu作为时钟; 1:Fosc作为时钟;
		;Bit2: TC0S16：TC0 溢出位选择； 0-8bit timer ；1-16bit timer
		;bit1:0 仿真必须清0
	
	BSR		TC0IE		;TC0 overflow enable bit(1=EN,0=DIS)	
	BSR		TC0TR		;启动TC0
	RETURN







