;//*****************************************************   
;//Copyright (c) 2024, 苏州华芯微电子股份有限公司
;//All rights reserved                                 
;//
;//文件名称: HS16F1880-1527 
;//摘    要: HS16F1880-1527解码功能演示
;//  	    PB0脚作为无线接收脚，解码成功PB1电平反转
;//
;//当前版本: 1.0                                      
;//作    者: 华芯微MCU组
;//完成日期: 2024.08.14
;//*****************************************************   
;***********************************************************
;files include
#include "HS16P1880.inc"
;***********************************************************
;用户IO定义
#define		OUT		PORTB,1
#define		RFIN	PORTB,0
;***********************************************************
;user general reg define
DELAY_US		EQU		40H
DELAY_MS_CNT	EQU		41H
LCODE           EQU     042H
MCODE           EQU     043H
HCODE           EQU     044H
REC_TMP         EQU     045H    ;防抖时间
REC_CNT         EQU     046H    ;测试脉冲计数
RELEASE_CNT     EQU     047H
HBIT            EQU     048H
LBIT            EQU     049H
FLAG1           EQU     04AH
FLAG            EQU     04BH
TIME_BASE		EQU     04CH
DELAY_OUTSIDE	EQU		04DH
DELAY_INSIDE	EQU		04EH

STATUS_BUF		EQU		07EH;中断保护寄存器必须放 0x70-0x7F不要动！！！
ACC_BUF			EQU		07FH;中断保护寄存器必须放 0x70-0x7F不要动！！！



#define F_ONCE          FLAG,0
#define F_ACK           FLAG,1
#define F_LEARN_WAIT    FLAG,2
#define F_RF_OK         FLAG,3       
#define F_ON_OFF        FLAG,4       
#define F_RF_WIDTH      FLAG,5       
#define F_RF_LEVEL      FLAG,6       
#define F_GET_DATA      FLAG,7


#define F_KEY_SCAN      FLAG1,0
#define F_SHORT_KEY     FLAG1,1
#define F_LONG_KEY      FLAG1,2
#define F_KEY_DELETE    FLAG1,3       
#define F_DATA_EQU      FLAG1,4
#define F_FRAME         FLAG1,5         ;码型说明      
#define F_MODE          FLAG1,6


;***********************************************************
;/函数入口地址
	ORG			00H
	NOP
	NOP
	GOTO		MAIN_SETUP
	
;/中断入口地址04H
	ORG		04H
	GOTO	INT_PRO
		
TAB_REC:
        ANDIA    003H           ;@0xf
        ADDAR    PCL,R
        BCR      F_RF_WIDTH     ;0  
        RETURN                  ;1
        RETURN                  ;2
        BSR      F_RF_WIDTH     ;3 
        RETURN                  ;4	
	
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	BCR	STATUS,5;切换到BANK0
	BCR	STATUS,6
;==========空=====================================	
	
;==============================================	
INT_BACK:	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS		;恢复STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0	;恢复ACC
	RETFIE
;//中断代码结束
	

;==========================================================================
;主程序开始
MAIN_SETUP:
	CALL	SYS_CPIO_INIT	;系统寄存器和GPIO配置
	CALL	CLR_ALL_RAM  	;清所有ram
	CALL	WDT_Init     	;看门狗初始化
MAIN_LOOP:
	CLRWDT	  				;清看门狗
	MOVIA	30
	CALL	DELAY
RF_CHECK:                        
        BSR     C
        BTRSS   RFIN
        BCR     C
        RLR     REC_TMP,R       ;接收电平信号左移
        MOVR    REC_TMP,A       ;
        CALL    TAB_REC         ;调表
        BTRSS   F_RF_WIDTH      ;接收无线到高低电平宽度标志
        GOTO    REC_LOW_LEVEL   ;接收低电平
REC_HIGH_LEVEL:
        BTRSS   F_GET_DATA
        GOTO    REC_HIGH_LEVEL_ON
        BCR     F_GET_DATA
        MOVIA   4              ;判断之前的低电平是否太短   
        SUBAR   LBIT,A
        BTRSS   C
        GOTO    REC_ERROR        
        MOVR    LBIT,A
        SUBAR   HBIT,A
        RRR     HCODE,R         ;24位数据左移
        RRR     MCODE,R         ;24位数据左移
        RRR     LCODE,R         ;24位数据左移        
        CLRR    HBIT
REC_HIGH_LEVEL_ON:        
        BSR     F_RF_LEVEL      ;无线电平标志
        INCR    HBIT,R          ;高电平加1
        MOVIA   60
        SUBAR   HBIT,A
        BTRSC   C               ;超过最大值，溢出      
        GOTO    REC_ERROR       ;超出范围，跳转
        CLRR    LBIT            ;清除低电平宽度暂存器
        GOTO    RF_CHECK_END    ;
        
REC_LOW_LEVEL:
        INCR    LBIT,R          ;低电平加1
        MOVIA   60              
        SUBAR   LBIT,A
        BTRSC   C               ;超过最大值，溢出   
        GOTO    REC_ERROR_L     ;低电平超出范围超出范围，跳转
        
        BTRSS   F_RF_LEVEL      ;无线电平标志
        GOTO    RF_CHECK_END    ;       
        BCR     F_RF_LEVEL      ;无线电平标志
        BSR     F_GET_DATA

        INCR    REC_CNT,R       ;接收码型的位数
        MOVIA   26
        SUBAR   REC_CNT,A
        BTRSC   C
        GOTO    REC_ERROR    

        MOVIA   4
        SUBAR   HBIT,A
        BTRSS   C
        GOTO    REC_ERROR       ;码宽太窄 出错   
        GOTO    RF_CHECK_END    ;返回主程序
REC_ERROR_L:
        MOVR    REC_CNT,A
        XORIA   25              ;判断是否为25个脉冲 
        BTRSC   Z
        GOTO    RF_CHECK_SUCCESS;25脉冲即为解码成功
        GOTO    REC_ERROR
;解码出错        
REC_ERROR:
        CLRR    REC_CNT         ;清接收码型位数
        CLRR    LBIT            ;清低电平宽度
        CLRR    HBIT            ;清高电平宽度
        BCR     F_RF_LEVEL      ;无线电平标志
        BCR     F_GET_DATA
        GOTO    RF_CHECK_END                  

;=========================================
RF_CHECK_END:                   ;等一帧码接完    
	GOTO	MAIN_LOOP		;主函数循环


;==================================================
;解码成功
;==================================================
RF_CHECK_SUCCESS:
        BCR     F_GET_DATA
        CLRR    REC_CNT        
        CLRR    HBIT
        CLRR    LBIT            
        CLRR    RELEASE_CNT
        
;============解码成功,PB1管脚反转=======================================        
        MOVIA	0X02
        XORAR	PORTB,R  
;=========================================
 		GOTO	MAIN_LOOP








;***********************************************************
;函数名：SYS_CPIO_INIT
;注意寄存器所在 bank 区域
;***********************************************************
SYS_CPIO_INIT:
	BCR	STATUS,5	;保证转到bank0/2再操作PORTB
	BCR	STATUS,6
	MOVIA	000H		;0000 0000
	MOVAR	PORTB
	BSR	STATUS,5	;转到bank1
	BCR	STATUS,6
	
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			//;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			//;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
			

	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN					
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
	
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	01H			;--00 0001 :PORTB输入输出配置寄存器 (0-OUT;1-IN) 
	MOVAR	TRISB		;0-OUT, 1-IN
	
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB变化中断唤醒寄存器 (1-EN;0=DIS)
	MOVAR	WUCON		;0-DIS, 1-EN
	
	BCR	STATUS,5	;转到bank0
	BCR	STATUS,6	
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;---- --11 :bit3:0 PORTA3:0下拉寄存器; bit7:4 PORTB3:0下拉寄存器;1-DIS;0-EN
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB开漏寄存器 (1-EN;0-DIS)
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FEH		;--11 1110 :PORTB上拉寄存器 (1-DIS;0-EN)
	MOVAR	PHCON		;0-EN, 1-DIS
	
	RETURN
	
;***********************************************************
;函数名：BANK0_RAM_CLR
;***********************************************************
CLR_ALL_RAM:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	RAM_CLR_LOOP
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时4个指令周期  Fcpu=4M时候延时1us，延时有误差
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP_US:	
	CLRWDT				;1;/清看门狗
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP_US	;2	
	RETURN		
	
	
	
;***********************************************************
;函数名：DELAY_MS
;传参：1-255ms
;返回值：
;功能：ms级延时
;引脚：
;备注：
;***********************************************************
DELAY_MS:    
        MOVAR   DELAY_OUTSIDE 
;---------------------------
DELAY_LOOP:
        MOVIA   192
        MOVAR   DELAY_INSIDE
DELAY_LOOP_INSIDE:
        CLRWDT
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        DECRSZ  DELAY_INSIDE,R
        GOTO    DELAY_LOOP_INSIDE
        DECRSZ  DELAY_OUTSIDE,R
        GOTO    DELAY_LOOP        
DELAY_2US:       
        CLRWDT
        NOP    
        NOP
        NOP	
        NOP	
        NOP	
        RETURN 
	
;***********************************************************
;函数名：WDT_Init
;***********************************************************
/****WDT overflow reset，have no wakeup funtions****；
则看门狗复位时间仅由烧录配置：288ms；512ms；766ms；1024ms；
*/
WDT_Init:
	CLRWDT
	BSR	STATUS,5	;RP0;转到bank1
	BCR	STATUS,6
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			//;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			//;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
			

	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN	
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
						
	BCR	STATUS,5	;转到bank0
	BCR	STATUS,6
	RETURN

/**
  * @brief  tc0定时器初始化函数
  *
  * @note   TC0 无重装载功能，要改变周期需要在中断里手动改变 TC0L的值
  * @note   - 本示例使用Fpcu的4分频作为TC0时钟，也就是TC0时钟为1Mhz
  *           
  * @retval None
  */
tc0_tim_init:
	
	BCR		STATUS,5;切换到BANK0
	BCR		STATUS,6
	
	MOVIA	060H		;0110 0000
	MOVAR	TC0M	    ;  fcpu=8m/2;     fcpu/4=1m 
	
	BSR		TC0IE		;TC0 中断使能
	
	BSR		TC0TR		;开启TC0定时器
	RETURN







