;***********************************************************
;单    位:苏州华芯微电子有限公司     (2022)           	   * 
;                                                          *
;文件名称:	HS23P1820_COMP							       *
;摘    要:							   					   *
;当期版本:	V1.0                                           *
;作    者:	LvBuWei                                   	   *
;开始日期:  2022-08-27                                     *
;完成日期:                                                 *
;                                                          *
;先前版本:                                                 *
;作    者:                                                 *
;创始日期:                                                 *
;***********************************************************

;***********************************************************
;files include
#include	"HS23P1820.inc"
;//------------------------------------------

;***********************************************************
; HS23P1820 DEFINE	REG
DELAY_US	EQU		70H

STATUS_BUF	EQU		07EH
ACC_BUF		EQU		07FH

;//------------------------------------------
;/自定义


;//------------------------------------------
;//;程序起始地址
;//------------------------------------------
	ORG		000H
	GOTO	MAIN
	
	
;/中断入口地址
	ORG		04H
	;GOTO	INT_PRO
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	
COMP_INT:	
	BTRSS	FCOMINTF
	GOTO	INT_BACK
	BCR		FCOMINTF		;/清中断
	
	MOVIA	04H
	XORAR	PB,1			;/在中断中PB2翻转
	
	BSR		RP0
	BSR		RP1
	BTRSC	CMPM,6			;/判断FCMPIF的值
	GOTO	FCMP_1_loop		;/FCMPIF为1
	GOTO	FCMP_0_loop		;/FCMPIF为0
	
FCMP_1_loop:
	BCR		RP0
	BCR		RP1
	BSR		PB,5			;/则PB5输出高电平
	GOTO	INT_BACK
FCMP_0_loop:
	BCR		RP0
	BCR		RP1
	BCR		PB,5			;/则PB5输出低电平
	GOTO	INT_BACK

INT_BACK:	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0
	RETFIE
	
;//------------------------------------------
;//;程序起始
;//------------------------------------------	
MAIN:
	CALL	BANK0_RAM_CLR
	CALL	GPIO_init
	CALL	COMP_init

WHILE_LOOP:
	MOVIA	08H
	XORAR	PB,1		;/PB3翻转
	MOVIA	200
	CALL	DELAY	;/延时2000个指令周期
	GOTO	WHILE_LOOP
	
	
	
;***********************************************************
;函数名：COMP_init
;传参：
;返回值：
;功能：比较器使能
;引脚：
;备注：
;***********************************************************
COMP_init:	
	BSR		STATUS,5		;转到bank1	
	BSR		STATUS,6		;转到bank3

	;/CMPCON(比较器控制寄存器)	
	MOVIA	01010100B 
	MOVAR	CMPCON
	
					;/bit1:COPOL	比较器输出极性选择	
					;/bit2:CVEN		比较器+端
					;/bit3:CPEN		比较器+端
					;/bit4:CODEB	输出滤波	
					;/bit5:FTCKS	输出使能滤波时钟选择	
					;/bit6:CMPIF	比较器转换标志	
					;/bit7:CMPEN	CMP 使能位	
	;/比较器负端输入选择寄存器
	MOVIA	01110000B 
	MOVAR	CMPM	;Bit6~Bit5：CPIINS[1:0]: 比较器负端输入选择
					;Bit4：XRVSEL 比较电压点档位选择
					;Bit3~Bit0：负端电压档位选择
	
	BSR		CMPEN		;/使能比较器
	BCR		STATUS,6	;转到bank1
	BSR		INTEN1,1	;/INTEN1(中断屏蔽寄存器1)	0-DIS 1-EN
						;/1bit:COMINTEN:端口比较器中断使能位	0bit:TKINTEN: TK中断使能位
	BCR		STATUS,5	;转到bank0
	BCR		INTFLAG1,1	
	BSR		INTEN,7
	RETURN
	


;***************************************************
;函数名：GPIO_init
;***************************************************
GPIO_init:
	BSR		STATUS,5	;转到bank1
	
	;OPTION_REG(BANK1)		
	MOVIA	0000H
	MOVAR	OPTION_REG	;/00-- -000	
						;/bit0~2:  	 PS2~PS0 预分频比率选择位
									;PS2~PS0 	WDT比率 
									;0 0 0		1:1
									;0 0 1		1:2 
									;0 1 0		1:4 
									;0 1 1		1:8 
									;1 0 0		1:16 
									;1 0 1		1:32 
									;1 1 0		1:64
									;1 1 1		1:128
						;/bit6:	INTEDG：外部中断触发方式选择位（PB0）
						;/bit7:	INT1EDG：外部中断 1 触发方式选择位（PB1）
						
	;/PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;/101- ----
	MOVAR	PCON		;0-DIS 1-EN
					    ;/5bit:WDT	看门狗定时器使能位
						;/6bit:EIS: IOB0/INT引脚定义位
						;/7bit:LVDT	低电压复位使能位
	
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	00H			;--00 0000 			
	MOVAR	TRISB		;0-OUT, 1-IN
	
	;PBIC0(BANK1)(PA口驱动选择寄存器)		
	MOVIA	00H			;--00 0000
	MOVAR	PBIC0		;0-DIS, 1-EN
	
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000
	MOVAR	WUCON		;0-DIS, 1-EN
	
	BCR		STATUS,5	;转到bank0
		
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;1111 ----
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FFH		;--11 1111
	MOVAR	PHCON		;0-EN, 1-DIS
	
	RETURN
	
;***********************************************************
;函数名：BANK0_RAM_CLR
;***********************************************************
BANK0_RAM_CLR:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
BANK0_RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	BANK0_RAM_CLR_LOOP	
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时10个指令周期
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP:	
	CLRWDT				;1;/清看门狗
	GOTO	$+1			;2
	GOTO	$+1			;2
	GOTO	$+1			;2
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP	;2	
	RETURN				;2
	