;***********************************************************
;单    位:苏州华芯微电子有限公司     (2022)           	   * 
;                                                          *
;文件名称:	HS23P1820_TC0&RTC						       *
;摘    要:							   					   *
;当期版本:	V1.0                                           *
;作    者:	LvBuWei                                   	   *
;开始日期:  2022-08-27                                     *
;完成日期:                                                 *
;                                                          *
;先前版本:                                                 *
;作    者:                                                 *
;创始日期:                                                 *
;***********************************************************


;***********************************************************
;files include
#include "HS23P1820.inc"

;***********************************************************
DELAY_US	EQU		040H

DELAY_s		EQU		071H	;秒
DELAY_m		EQU		073H	;分
DELAY_h		EQU		074H	;时

STATUS_BUF	EQU		07EH
ACC_BUF		EQU		07FH
;***********************************************************
.CODE
;/函数入口地址
	ORG		00H
	GOTO	INITIAL


;/中断入口地址
	ORG		04H
	;GOTO	INT_PRO
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	
	BTRSS	FTC0IF
	GOTO	INT_BACK
	BCR		FTC0IF
	
	MOVIA	02H
	XORAR	PB,1
	
;中断 一次 1s	
	DECRSZ	DELAY_s,1		;DELAY_s - 1
	GOTO 	INT_BACK
	MOVIA	60				
	MOVAR	DELAY_s			;60s循环
	
END_S:
	MOVR	DELAY_m,0		;/判断DELAY_m是否未0
	BTRSS	FZ
	GOTO	END_S_END	
	
	MOVIA	60			
	MOVAR	DELAY_m			;/不为0则借位h，m借位借满60
	GOTO	END_M
	
END_S_END:	
	DECR	DELAY_m,1		;/不为0则借位m	DELAY_m-1
	GOTO 	INT_BACK
	
END_M:						;/为0则要借位h	
	MOVR	DELAY_h,0		;/判断h是否为0
	BTRSS	STATUS,2
	GOTO	END_M_END			
	
	BSR		PB,2			;计时时间到
	GOTO	INT_BACK
	
END_M_END:	
	DECR	DELAY_h,1
	;GOTO	INT_BACK
		
INT_BACK:	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0
	RETFIE



;***********************************************************
;***********************************************************
INITIAL:

	CALL	BANK0_RAM_CLR
	CALL	GPIO_init
	
	MOVIA	60
	MOVAR	DELAY_s
	MOVIA	59
	MOVAR	DELAY_m
	MOVIA	0
	MOVAR	DELAY_h

	BSR		STATUS,5

	MOVIA	00001010B 
	MOVAR	OSCM		;/选择外部低速作为TC0时钟源
						;Bit6：WAKEMODE：睡眠唤醒后系统时钟选择位;0=InsideLowRC,1=HighRC
						;Bit5：GREENEN：绿色模式使能位		;0=GeneralMode，1=GreenMode
						;Bit4：SLT0CON：TC0低速时钟控制位(用于唤醒睡眠、绿色);0=HighRC,1=LowRC
						;Bit3：SLCON：内外低速时钟控制位	;0=OpenLowRC,1=CloseLowRC
						;Bit2：XTSEL：内外低速选择位		;0=InsideLowRC,1=OutSideLowRC
						;Bit1：STPHX：内部高速振荡器控制位	;0=Work,1=Stop
						;Bit0：CLKMD：系统时钟模式控制位	;0=GeneralMode，1=LowMode
	
	BCR		STATUS,5
	MOVIA 	00H 
	MOVAR	TC0L
	MOVIA 	00100000B 
	MOVAR	TC0M		;Bit7：TC0TR:TC0 启动控制位。
						;Bit6~Bit4：TC0S[2:0]:TC0 分频选择位
						;Bit3：TCCKS:TC0 时钟信号控制位	
	
	
	BCR		INTFLAG,3
	BSR		INTEN,3
	BSR		INTEN,7
	BSR		TC0M,7
	

	GOTO 	MAIN
	
;***********************************************************
;MIAN
;***********************************************************
MAIN:
	CLRWDT
	BSR		PB,0
	NOP
	NOP
	NOP
	BCR		PB,0
	NOP
	NOP
	GOTO	MAIN

;***************************************************
;函数名：GPIO_init
;***************************************************
GPIO_init:
	BSR		STATUS,5	;转到bank1
	
	;OPTION_REG(BANK1)		
	MOVIA	0000H
	MOVAR	OPTION_REG	;/00-- -000	
						;/bit0~2:  	 PS2~PS0 预分频比率选择位
									;PS2~PS0 	WDT比率 
									;0 0 0		1:1
									;0 0 1		1:2 
									;0 1 0		1:4 
									;0 1 1		1:8 
									;1 0 0		1:16 
									;1 0 1		1:32 
									;1 1 0		1:64
									;1 1 1		1:128
						;/bit6:	INTEDG：外部中断触发方式选择位（PB0）
						;/bit7:	INT1EDG：外部中断 1 触发方式选择位（PB1）
						
	;/PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----
	MOVAR	PCON		;0-DIS 1-EN
					    ;/5bit:WDT	看门狗定时器使能位
						;/6bit:EIS: IOB0/INT引脚定义位
						;/7bit:LVDT	低电压复位使能位
	
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	00H			;--00 0000 			
	MOVAR	TRISB		;0-OUT, 1-IN
	
	;PBIC0(BANK1)(PA口驱动选择寄存器)		
	MOVIA	00H			;--00 0000
	MOVAR	PBIC0		;0-DIS, 1-EN
	
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000
	MOVAR	WUCON		;0-DIS, 1-EN
	
	BCR		STATUS,5	;转到bank0
		
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;1111 ----
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FFH		;--11 1111
	MOVAR	PHCON		;0-EN, 1-DIS
	
	RETURN
	 
	
;***********************************************************
;函数名：BANK0_RAM_CLR 
;功能：清bank0
;***********************************************************
BANK0_RAM_CLR:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
BANK0_RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	BANK0_RAM_CLR_LOOP	
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时10个指令周期
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP:	
	CLRWDT				;1;/清看门狗
	GOTO	$+1			;2
	GOTO	$+1			;2
	GOTO	$+1			;2
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP	;2	
	RETURN				;2
	