;//*****************************************************   
;//Copyright (c) 2025, 苏州华芯微电子股份有限公司
;//All rights reserved                                 
;//
;//文件名称: HS16F1886_UART_SEND 
;//摘    要: HS16F1886_UART_SEND功能演示
;//  	    模拟串口发送数据，  9600波特率，无校验，8位数据位，一位停止位 ：  96-N-8-1格式
;//         该程序系统时钟为   8M/2分频;   PB0管脚作为串口数据发送脚   TX
;//当前版本: 1.0                                      
;//作    者: 华芯微MCU组
;//完成日期: 2025.06.20
;//*****************************************************   

;***********************************************************
;files include
#include "HS16P1886.inc"

;A		EQU	0x0
;R		EQU	0x1
;***********************************************************
;用户IO定义
#define		TX_O	PORTB,0
;***********************************************************
;通用寄存器定义
DELAY_US		EQU		40H
DELAY_MS_CNT	EQU		41H
DATA_TX			EQU		42H
TEMP_1			EQU		43H
TEMP_2			EQU		44H
DELAY_OUTSIDE	EQU		45H
DELAY_INSIDE	EQU		46H

STATUS_BUF	EQU		07EH;中断保护寄存器必须放 0x70-0x7F不要动！！！
ACC_BUF		EQU		07FH;中断保护寄存器必须放 0x70-0x7F不要动！！！

;==================================
;常量定义
;==================================

SDA_OUTPUT      EQU     000H                                  
SDA_INPUT       EQU     040H 



;***********************************************************
;/函数入口地址
	ORG	00H
	NOP
	NOP
	GOTO	MAIN_SETUP
;***********************************************************
;/中断入口地址04H
	ORG	04H
	GOTO	INT_PRO
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	BCR		STATUS,5
;------------------------------------------------
;           空
;------------------------------------------------
INT_BACK:   ;中断返回	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS		;恢复STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0	;恢复ACC
	RETFIE
;//中断代码结束
	

;==========================================================================
;系统初始化
MAIN_SETUP:
	CALL	SYS_CPIO_INIT	;系统寄存器和GPIO配置
	CALL	CLR_ALL_RAM  	;清所有ram
	CALL	WDT_Init     	;看门狗初始化
	CLRWDT					;清看门狗
	BCR	STATUS,5		;保证转到bank0/2再操作PORTB
	
MAIN:;主函数循环
	CLRWDT	 
	MOVIA	0X3C
	CALL	SER_SEND_DATA
	MOVIA	0X55
	CALL	SER_SEND_DATA
	MOVIA	0XAA
	CALL	SER_SEND_DATA
;------------------------------------------	
	MOVIA	100
	CALL	DELAY_MS
	GOTO	MAIN		
;***********************************************************
;函数名：SER_SEND_DATA
;功能： 模拟串口发送数据
;引脚： PB0管脚作为串口数据发送脚   TX
;备注：   9600波特率，无校验，8位数据位，一位停止位 ：  96-N-8-1格式   
;***********************************************************
SER_SEND_DATA:
	MOVAR	DATA_TX
	MOVIA	0X08
	MOVAR	TEMP_1
	BCR    	TX_O
	MOVIA	138;
	MOVAR	TEMP_2
SER_DELAY1:
	DECRSZ	TEMP_2,R
	GOTO	SER_DELAY1
	
SER_LOOP:
	RRR   	DATA_TX,R
	BTRSC 	C
	BSR    	TX_O
	BTRSS 	C
	BCR    	TX_O
    MOVIA   136
	MOVAR   TEMP_2
SER_DELAY2:	
	DECRSZ	TEMP_2,R
	GOTO	SER_DELAY2
	DECRSZ	TEMP_1,R
	GOTO     SER_LOOP			
	BSR    	TX_O
	MOVIA   0XEF
	MOVAR   TEMP_2
SER_DELAY3:	
	DECRSZ	TEMP_2,R
	GOTO	SER_DELAY3	
	CLRWDT	
	RETURN



;***********************************************************
;函数名：SYS_CPIO_INIT
;注意寄存器所在 bank 区域
;***********************************************************
SYS_CPIO_INIT:
	BSR		STATUS,5	;转到bank1
	
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
			
	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN
						
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
	
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	00H			;--00 0001 :PORTB输入输出配置寄存器 (0-OUT;1-IN) 
	MOVAR	TRISB		;0-OUT, 1-IN
	
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB变化中断唤醒寄存器 (1-EN;0=DIS)
	MOVAR	WUCON		;0-DIS, 1-EN
		
		;PBIC0(BANK1)(PORB驱动低电平控制寄存器)
		MOVIA	00H			;--00 0000 :
		MOVAR	PBIC0		;0-DIS, 1-EN
        
		;XTCON(BANK1)(外振模式控制寄存器)
		;MOVIA	00H			;--00 0000 :
		;MOVAR	XTCON		;默认开启-与config同时有效 外振才生效
				;bit5: XTSEN1：外振软件增强使能位 1（与上位机配置共同控制） 0-en;1-dis
				;bit4: XTSEN0：外振软件增强使能位 0（与上位机配置共同控制） 0-en;1-dis
				;bit3: XTEN：外振软件使能位（与上位机配置共同控制）		 0-en;1-dis
				;bit2: XT_TC0S：TC0 低速时钟选择		0-内部低速时钟；1-外部32.768K 
				;bit1: XT_LRCS：低速模式系统时钟选择	0-dis ; 1-EN
				;bit0:	XT_MONE：外振监测使能
	
	BCR	STATUS,5	;转到bank0
		
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;---- --11 :bit3:0 PORTA3:0下拉寄存器; bit7:4 PORTB3:0下拉寄存器;1-DIS;0-EN
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB开漏寄存器 (1-EN;0-DIS)
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FFH		;--11 1110 :PORTB上拉寄存器 (1-DIS;0-EN)
	MOVAR	PHCON		;0-EN, 1-DIS
	
		;DRVC0(BANK0)(PB0 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC0		;0-EN, 1-DIS
		
		;DRVC1(BANK0)(PB1 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC1		;0-EN, 1-DIS
		
		;DRVC2(BANK0)(PB2 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC2		;0-EN, 1-DIS
	
	RETURN
	
;***********************************************************
;函数名：BANK0_RAM_CLR
;***********************************************************
CLR_ALL_RAM:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	RAM_CLR_LOOP
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时4个指令周期  Fcpu=4M时候延时1us，延时有误差
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP_US:	
	CLRWDT				;1;/清看门狗
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP_US	;2	
	RETURN				;2	
;***********************************************************
;函数名：DELAY_MS
;传参：1-255ms
;返回值：
;功能：ms级延时
;引脚：
;备注：
;***********************************************************
DELAY_MS:    
        MOVAR   DELAY_OUTSIDE 
;---------------------------
DELAY_LOOP:
        MOVIA   197
        MOVAR   DELAY_INSIDE
DELAY_LOOP_INSIDE:
        CLRWDT
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        DECRSZ  DELAY_INSIDE,R
        GOTO    DELAY_LOOP_INSIDE
        DECRSZ  DELAY_OUTSIDE,R
        GOTO    DELAY_LOOP        
DELAY_2US:       
        CLRWDT
        NOP    
        NOP
        NOP	
        NOP	
        NOP	
        RETURN 
;***********************************************************
;函数名：WDT_Init
;***********************************************************
/****WDT overflow reset，have no wakeup funtions****；
则看门狗复位时间仅由烧录配置：288ms；512ms；766ms；1024ms；
*/
WDT_Init:
	CLRWDT
	BSR		STATUS,5	;RP0;转到bank1
	
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
			

	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H	;101- ----   	
	MOVAR	PCON	;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN
					
					;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
						
	BCR		STATUS,5	;转到bank0
	RETURN
