;//*****************************************************   
;//Copyright (c) 2025, 苏州华芯微电子股份有限公司
;//All rights reserved                                 
;//
;//文件名称: HS16F1886-比较器
;//摘    要: HS16F1886-比较器功能演示
;//  	    使用内部1V基准与VDD 比较电压1V，发生中断后翻转PB0
;//
;//当前版本: 1.0                                      
;//作    者: 华芯微MCU组
;//完成日期: 2025.06.20
;//*****************************************************   

;***********************************************************
;files include
#include "HS16P1886.inc"
;***********************************************************
;用户IO定义
#define		OUT	PORTB,1
#define		IN	PORTB,0


;***********************************************************
;user general reg define
DELAY_US		EQU		40H
DELAY_MS_CNT	EQU		41H
DELAY_OUTSIDE	EQU		042H
DELAY_INSIDE	EQU		043H



STATUS_BUF	    EQU		07EH;中断保护寄存器必须放 0x70-0x7F不要动！！！
ACC_BUF		    EQU		07FH;中断保护寄存器必须放 0x70-0x7F不要动！！！
;***********************************************************
;/函数入口地址
	ORG			00H
	NOP
	NOP
	GOTO		MAIN_SETUP
	
;/中断入口地址04H
	ORG		04H
	GOTO	INT_PRO
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	BCR		STATUS,5
	BCR		STATUS,6
	
COMP_INT:	
	BTRSS	FCOMINTF
	GOTO	INT_BACK
	BCR		FCOMINTF		;发生比较器中断就翻转
	MOVIA	02H
	XORAR	PB,1
	GOTO	INT_BACK
	

	
INT_BACK:	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS		;恢复STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0	;恢复ACC
	RETFIE
;//中断代码结束
	
	
CMPCON_INIT:


	;相关寄存器汇总
	;CMPCON 比较器控制寄存器
	;CMPM   比较器负端输入选择寄存器
	;COMINTF  端口比较器翻转标志位
	;COMINTEN 使能比较器中断 
	;比较器正端 PB0 / 1.0V / 0.1V 选择优先级如下：1.0V＞PB0＞0.1V。即同时使能情况下，正端选择为 1.0V。
	;若比较器输出极性不取反，则正端＞负端，比较器输出 1，中断使能可进中断；正端＜负端，则比较器输出 0，不进中断。
	;若比较器输出极性取反，则反之，正端＜负端，比较器输出 1，中断使能可进中断；正端＞负端，比较器输出 0，不进中断

	;BANK3
	BSR		STATUS,5		
	BSR		STATUS,6		
	

	;使用内部1V  基准
	MOVIA	094H		
	MOVAR	CMPCON
	
	;CMPCON = 0xD4;	
	
		;Bit7：CMPEN: CMP 使能位							1:使能								0:禁止
		;Bit6：CMPIF: 比较器转换标志					1:比较输出1					0:比较输出0
		;Bit5：FTCKS: 输出使能滤波时钟选择    1:低速时钟32K				0:系统时钟
		;Bit4：CODEB: 输出滤波								1:使能，3个时钟延迟		0:禁止
		;Bit3：CPEN+: 比较器+端设置  					1:使能,接PB0端口     0:禁止
		;Bit2：CVEN+: 比较器+端设置						1:使能,接内部1V基准		0:禁止
		;Bit1：COPOL: 比较器输出极性选择			1:取反
        ;Bit0：XRVSEL0：比较电压点档位选择	{与 XRVSEL1（CMPM.bit4）构成比较电压档位选择}

	; 比较VDD 3.55V
	
	MOVIA	011H		
	MOVAR	CMPM
	
	;CMPM = 0x11;	//0001 0000 //CMPCON'-'negative CONFIG[VDD]；XRVSEL=1；VRS<3:0>=0；(voltage of cmopare:4.69);
		;Bit7:XCV1EN+ 比较器+端设置						1:使能接内部0.1V			0:禁止
		;Bit6~Bit5：CPIINS[1:0]: 比较器负端输入选择;	00=VDD;01=PB4;10=禁止;11=PB1
		;Bit4：XRVSEL1 比较电压点档位选择
		;Bit3~Bit0：负端电压档位选择

;内部1V基准
		;负端电压档位选择		 比较的电压点（V）
		;VRS<3:0>			XRVSEL<1:0>=00		XRVSEL<1:0>=10		XRVSEL<1:0>=01		XRVSEL<1:0>=11	
		;	0000			 - 0.97 -				0.97                0.97               0.97			
		;	0001				4.15				3.45                4.95               4.10
		;	0010				3.90				3.25                 \                  \  
		;	0011				3.70				3.05                4.30               3.55
		;	0100				3.50				2.90                 \                  \  
		;	0101				3.35				2.75                3.80               3.20
		;	0110				3.20				2.65                 \                  \  
		;	0111				3.05				2.55                3.40               2.85
		;	1000				2.90				2.45                 \                  \  
		;	1001				2.70				2.25                2.90               2.45
		;	1010				2.35				1.95                 \                  \  
		;	1011				2.05				1.70                2.15               1.80
		;	1100				1.85				1.55                 \                  \  
		;	1101				1.55				1.25                1.55               1.25
		;	1110				1.35				1.10                 \                  \  
		;	1111				1.15				0.97                1.15               0.97

;使用内部0.1V 基准
		;负端电压档位选择 比较的电压点（V）
		;VRS<3:0>			XRVSEL<1:0>=00		XRVSEL<1:0>=10		XRVSEL<1:0>=01		XRVSEL<1:0>=11	
		;	0000				0.105				0.105               0.105              0.105
		;	0001				0.455				0.375               0.525              0.430
		;	0010				0.425				0.355                \                  \  
		;	0011				0.400				0.335               0.455              0.370
		;	0100				0.385				0.320                \                  \  
		;	0101				0.360				0.305               0.400              0.320
		;	0110				0.350				0.290                \                  \  
		;	0111				0.335				0.275               0.355              0.290
		;	1000				0.320				0.265                \                  \  
		;	1001				0.295				0.245               0.310              0.255
		;	1010				0.255				0.215                \                  \  
		;	1011				0.225				0.185               0.230              0.190
		;	1100				0.200				0.170               0.200              0.170
		;	1101				0.170				0.140               0.170              0.140
		;	1110				0.145				0.120               0.145              0.125
		;	1111				0.125				0.105               0.125              0.105


	BSR		STATUS,5	;转到bank1
	BCR		STATUS,6
	BSR		INTEN1,1	;/INTEN1(中断屏蔽寄存器1)	0-DIS 1-EN
		
	BCR		STATUS,5	;转到bank0
	BCR		STATUS,6
	BCR		INTFLAG1,1	;清中断标志位
	BSR		INTEN,7     ;GIE
	RETURN



RETURN
;==========================================================================
;主程序开始
MAIN_SETUP:
	CALL	SYS_CPIO_INIT	;系统寄存器和GPIO配置
	CALL	CLR_ALL_RAM  	;清所有ram
	CALL	WDT_Init     	;看门狗初始化
	CALL	CMPCON_INIT		;比较器初始化
	CLRWDT					;清看门狗
	
MAIN_LOOP:
	CLRWDT	  				;清看门狗
	MOVIA	100
	CALL	DELAY_MS
	
	MOVIA	0X01
	XORAR	PORTB,R
	
	
	
	GOTO	MAIN_LOOP		;主函数循环

;***********************************************************
;函数名：SYS_CPIO_INIT
;注意寄存器所在 bank 区域
;***********************************************************
SYS_CPIO_INIT:
	BSR		STATUS,5	;转到bank1
	BCR		STATUS,6
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge		
	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN					
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	00H			;--00 0001 :PORTB输入输出配置寄存器 (0-OUT;1-IN) 
	MOVAR	TRISB		;0-OUT, 1-IN
	
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB变化中断唤醒寄存器 (1-EN;0=DIS)
	MOVAR	WUCON		;0-DIS, 1-EN
	
		;PBIC0(BANK1)(PORB驱动低电平控制寄存器)
		MOVIA	00H			;--00 0000 :
		MOVAR	PBIC0		;0-DIS, 1-EN
        
		;XTCON(BANK1)(外振模式控制寄存器)
		MOVIA	00H			;--00 0000 :
		MOVAR	XTCON		;
				;bit5: XTSEN1：外振软件增强使能位 1（与上位机配置共同控制） 0-en;1-dis
				;bit4: XTSEN0：外振软件增强使能位 0（与上位机配置共同控制） 0-en;1-dis
				;bit3: XTEN：外振软件使能位（与上位机配置共同控制）		 0-en;1-dis
				;bit2: XT_TC0S：TC0 低速时钟选择		0-内部低速时钟；1-外部32.768K 
				;bit1: XT_LRCS：低速模式系统时钟选择	0-dis ; 1-EN
				;bit0:	XT_MONE：外振监测使能
	
	BCR		STATUS,5	;转到bank0
	BCR		STATUS,6	
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;---- --11 :bit3:0 PORTA3:0下拉寄存器; bit7:4 PORTB3:0下拉寄存器;1-DIS;0-EN
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB开漏寄存器 (1-EN;0-DIS)
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FFH		;--11 1110 :PORTB上拉寄存器 (1-DIS;0-EN)
	MOVAR	PHCON		;0-EN, 1-DIS
	
		;DRVC0(BANK0)(PB0 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC0		;0-EN, 1-DIS
		
		;DRVC1(BANK0)(PB1 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC1		;0-EN, 1-DIS
		
		;DRVC2(BANK0)(PB2 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC2		;0-EN, 1-DIS
	
	RETURN
	
;***********************************************************
;函数名：BANK0_RAM_CLR
;***********************************************************
CLR_ALL_RAM:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	RAM_CLR_LOOP
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时4个指令周期  Fcpu=4M时候延时1us，延时有误差
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP_US:	
	CLRWDT				;1;/清看门狗
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP_US	;2	
	RETURN				;2	
;***********************************************************
;函数名：DELAY_MS
;传参：1-255ms
;返回值：
;功能：ms级延时
;引脚：
;备注：
;***********************************************************
DELAY_MS:    
        MOVAR   DELAY_OUTSIDE 
;---------------------------
DELAY_LOOP:
        MOVIA   197
        MOVAR   DELAY_INSIDE
DELAY_LOOP_INSIDE:
        CLRWDT
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        DECRSZ  DELAY_INSIDE,R
        GOTO    DELAY_LOOP_INSIDE
        DECRSZ  DELAY_OUTSIDE,R
        GOTO    DELAY_LOOP        
DELAY_2US:       
        CLRWDT
        NOP    
        NOP
        NOP	
        NOP	
        NOP	
        RETURN  
;***********************************************************
;函数名：WDT_Init
;***********************************************************
/****WDT overflow reset，have no wakeup funtions****；
则看门狗复位时间仅由烧录配置：288ms；512ms；766ms；1024ms；
*/
WDT_Init:
	CLRWDT
	BSR		STATUS,5	;RP0;转到bank1
	BCR		STATUS,6
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge			
	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H	;101- ----   	
	MOVAR	PCON	;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN
					;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
						
	BCR		STATUS,5;转到bank0
	BCR		STATUS,6
	RETURN
