;//*****************************************************   
;//Copyright (c) 2025, 苏州华芯微电子股份有限公司
;//All rights reserved                                 
;//
;//文件名称: HS16P1886_SLEEP_TP0_WAKEUP 
;//摘    要: HS16P1886_SLEEP_TP0_WAKEUP功能演示 
;//当前版本: 1.0                                      
;//作    者: 华芯微MCU组
;//完成日期: 2025.06.20
;//*****************************************************   

;***********************************************************
;files include
#include "HS16P1886.inc"

;A		EQU	0x0
;R		EQU	0x1
;***********************************************************
;用户IO定义
#define		LED1	PORTB,2
;***********************************************************
;通用寄存器定义
DELAY_US		EQU		40H
DELAY_MS_CNT	EQU		41H
DELAY_OUTSIDE	EQU		042H
DELAY_INSIDE	EQU		043H





STATUS_BUF	    EQU		07EH;中断保护寄存器必须放 0x70-0x7F不要动！！！
ACC_BUF		    EQU		07FH;中断保护寄存器必须放 0x70-0x7F不要动！！！

;==================================
;常量定义
;==================================
SDA_OUTPUT      EQU     000H                                  
SDA_INPUT       EQU     040H 
;***********************************************************
;/函数入口地址
	ORG	00H
	NOP
	NOP
	GOTO	MAIN_SETUP
;***********************************************************
;/中断入口地址04H
	ORG	04H
	GOTO	INT_PRO
INT_PRO:	
	MOVAR	ACC_BUF		;保存ACC
	SWAPR	STATUS,0
	MOVAR	STATUS_BUF	;保存STATUS
	BCR		STATUS,5
	BCR		STATUS,6
;------------------------------------------------
	CLRR	INTFLAG
	MOVIA	0X30
	XORAR	PORTB,R
	MOVIA	56
	MOVAR	PWM0TL
;------------------------------------------------
INT_BACK:   ;中断返回	
	SWAPR	STATUS_BUF,0
	MOVAR	STATUS		;恢复STATUS
	SWAPR	ACC_BUF,1
	SWAPR	ACC_BUF,0	;恢复ACC
	RETFIE
;//中断代码结束
	

;==========================================================================
;系统初始化
MAIN_SETUP:
	CALL	SYS_CPIO_INIT	;系统寄存器和GPIO配置
	CALL	CLR_ALL_RAM  	;清所有ram
	CALL	WDT_Init     	;看门狗初始化
	CALL	TP0_8BIT_WAKEUP_INIT        ;端口变化中断初始化
	CLRWDT					;清看门狗
	BCR	STATUS,5		;保证转到bank0/2再操作PORTB
	BCR		STATUS,6
MAIN:;主函数循环
	CLRWDT	 
;----------------------------------------	
	CALL	GREEN_SET  ;进入绿色模式
;----------------------------------------
	GOTO	MAIN		
;***********************************************************
;函数名：GREEN_SET
;功能：  进入绿色模式,
;引脚：
;备注： 进入绿色模式  " BSR		GREENEN "
;       该函数进入绿色模式之前，关闭看门狗，设置低速时钟作为系统时钟；  绿色唤醒后，打开看门狗，时钟调为高速时钟作为系统时钟
;***********************************************************
GREEN_SET:
	BSR		STATUS,5
	BCR		STATUS,6
	CLRR	PCON
	MOVIA	0X53
	MOVAR	OSCM	;Bit6：WAKEMODE：睡眠唤醒后系统时钟选择位;0=InsideLowRC,1=HighRC
					;Bit5：GREENEN：绿色模式使能位		;0=GeneralMode，1=GreenMode
					;Bit4：SLT0CON：TC0低速时钟控制位(用于唤醒睡眠、绿色);0=HighRC,1=LowRC
					;Bit3：SLCON：内外低速时钟控制位	;0=OpenLowRC,1=CloseLowRC
					;Bit2：XTSEL：内外低速选择位		;0=InsideLowRC,1=OutSideLowRC
					;Bit1：STPHX：内部高速振荡器控制位	;0=Work,1=Stop
					;Bit0：CLKMD：系统时钟模式控制位	;0=GeneralMode，1=LowMode
	NOP
	BSR		GREENEN
	NOP
	BCR		STATUS,5
	BCR		STATUS,6
;--------唤醒后，时钟改为高速RC时钟-----------------------------------
	BSR		STATUS,5
	MOVIA	0X40
	MOVAR	OSCM	;Bit6：WAKEMODE：睡眠唤醒后系统时钟选择位;0=InsideLowRC,1=HighRC
					;Bit5：GREENEN：绿色模式使能位		;0=GeneralMode，1=GreenMode
					;Bit4：SLT0CON：TC0低速时钟控制位(用于唤醒睡眠、绿色);0=HighRC,1=LowRC
					;Bit3：SLCON：内外低速时钟控制位	;0=OpenLowRC,1=CloseLowRC
					;Bit2：XTSEL：内外低速选择位		;0=InsideLowRC,1=OutSideLowRC
					;Bit1：STPHX：内部高速振荡器控制位	;0=Work,1=Stop
					;Bit0：CLKMD：系统时钟模式控制位	;0=GeneralMode，1=LowMode
	BSR		WDTE    ;打开看门狗
	BCR		STATUS,5
	BCR		STATUS,6
	RETURN

;***********************************************************
;函数名：TP0_8BIT_WAKEUP_INIT
;传参：
;返回值：
;功能：
;备注： 时钟必须要选择FOSC
 ;     
;      
;***********************************************************
TP0_8BIT_WAKEUP_INIT:	
	BCR		STATUS,5
	BSR		STATUS,6
	;BSR		RP1	;goto bank2
	;定时器周期寄存器
	MOVIA	56
	MOVAR	PWM0TL
	
	;控制寄存器
	MOVIA	0xC1	;11-0 0011 ;FOSC/4
	MOVAR	PWM0C	;Bit4：PWMVS2：PWM1X 输出取反位; 	0=DIS,1=EN
					;Bit3：PWMVS1：PWM01X 输出取反位; 	0=DIS,1=EN
					;Bit2：PWMVS0：PWM0X 输出取反位; 	0=DIS,1=EN
					;[Bit7~Bit6:Bit1~Bit0]：CK0[3:0]：PWMX0时钟源选择位

	;PWM输出端口选择
	MOVIA	0x00	;--00 0000
	MOVAR	PWMPSCON;Bit5~Bit4：PWM1S[1:0]：PWM1X 输出端口选择； 	00=PB0,01=PA0,10=PA4,11=null
					;Bit3~Bit2：PWM01S[1:0]：PWM01X 输出端口选择； 	00=PB1,01=PB6,10=PB7,11=null
					;Bit1~Bit0：PWM0S[1:0]：PWM0X 输出端口选择； 	00=PB2,01=PA1,10=PA5,11=PB3
	
	;PWM是能寄存器
	MOVIA	0x80	;1-00 0000
	MOVAR	PWM0EN	;Bit7：TP0EN:TP0定时器总使能;				0=DIS,1=EN
					;Bit5：TP0SEL8: 8/ 12 位定时器选择位;		0=8bit,1=12bit
					;Bit4：PWM1XEN:PWM1X输出控制位;				0=DIS,1=EN
					;Bit2：PWM01XEN:PWM01X输出控制位;			0=DIS,1=EN
					;Bit1：PWM0XEN:PWM0X输出控制位;				0=DIS,1=EN
					;Bit0：LOADEN:PWM重装使能(重装周期寄存器);	0=DIS,1=EN
					
	;BCR		RP1	;goto bank0
	
	BCR		STATUS,5
	BCR		STATUS,6
	
	BCR		FTP0IF
	BSR		FTP0IE
	BSR		FGIE
	RETURN
;***********************************************************
;函数名：SYS_CPIO_INIT
;注意寄存器所在 bank 区域
;***********************************************************
SYS_CPIO_INIT:

	BSR		STATUS,5	;转到bank1
	BCR		STATUS,6
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
			

	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN
						
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
	
	;TRISB(BANK1)(I/O口PB控制寄存器)
	MOVIA	00H			;--00 0001 :PORTB输入输出配置寄存器 (0-OUT;1-IN) 
	MOVAR	TRISB		;0-OUT, 1-IN
	
	;WUCON(BANK1)(PORB输入状态变化中断/唤醒控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB变化中断唤醒寄存器 (1-EN;0=DIS)
	MOVAR	WUCON		;0-DIS, 1-EN
	
		;PBIC0(BANK1)(PORB驱动低电平控制寄存器)
		MOVIA	00H			;--00 0000 :
		MOVAR	PBIC0		;0-DIS, 1-EN
        
		;XTCON(BANK1)(外振模式控制寄存器)
		;MOVIA	00H			;--00 0000 :
		;MOVAR	XTCON		;
				;bit5: XTSEN1：外振软件增强使能位 1（与上位机配置共同控制） 0-en;1-dis
				;bit4: XTSEN0：外振软件增强使能位 0（与上位机配置共同控制） 0-en;1-dis
				;bit3: XTEN：外振软件使能位（与上位机配置共同控制）		 0-en;1-dis
				;bit2: XT_TC0S：TC0 低速时钟选择		0-内部低速时钟；1-外部32.768K 
				;bit1: XT_LRCS：低速模式系统时钟选择	0-dis ; 1-EN
				;bit0:	XT_MONE：外振监测使能
	
	BCR	STATUS,5	;转到bank0
	BCR		STATUS,6	
	;PDCON(BANK0)(内部下拉控制寄存器)
	MOVIA	0FFH		;---- --11 :bit3:0 PORTA3:0下拉寄存器; bit7:4 PORTB3:0下拉寄存器;1-DIS;0-EN
	MOVAR	PDCON		;0-EN, 1-DIS	
	
	;ODCON(BANK0)(PB漏极开路控制寄存器)
	MOVIA	00H			;--00 0000 :PORTB开漏寄存器 (1-EN;0-DIS)
	MOVAR	ODCON		;0-DIS, 1-EN
	
	;PHCON(BANK0)(PB 内部上拉控制寄存器)
	MOVIA	0FFH		;--11 1110 :PORTB上拉寄存器 (1-DIS;0-EN)
	MOVAR	PHCON		;0-EN, 1-DIS
	
		;DRVC0(BANK0)(PB0 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC0		;0-EN, 1-DIS
		
		;DRVC1(BANK0)(PB1 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC1		;0-EN, 1-DIS
		
		;DRVC2(BANK0)(PB2 端口大驱动控制寄存器)
		MOVIA	0FFH		;---- -000 :
		MOVAR	DRVC2		;0-EN, 1-DIS

	RETURN
	
;***********************************************************
;函数名：BANK0_RAM_CLR
;***********************************************************
CLR_ALL_RAM:
	MOVIA	0X3F
	MOVAR	40H
	MOVIA	0X7F
	MOVAR	FSR
	
RAM_CLR_LOOP:	
	CLRR	INDF
	DECR	FSR,1
	DECRSZ	40H,1
	GOTO	RAM_CLR_LOOP
	RETURN
	
;***********************************************************
;函数名：DELAY
;传参：循环体调用次数
;返回值：
;功能：延时4个指令周期  Fcpu=4M时候延时1us，延时有误差
;引脚：
;备注：
;***********************************************************
DELAY:					
	MOVAR	DELAY_US	
DELAY_LOOP_US:	
	CLRWDT				;1;/清看门狗
	DECRSZ	DELAY_US,1	;1/(2)
	GOTO	DELAY_LOOP_US	;2	
	RETURN				;2	
;***********************************************************
;函数名：DELAY_MS
;传参：1-255ms
;返回值：
;功能：ms级延时
;引脚：
;备注：
;***********************************************************
DELAY_MS:    
        MOVAR   DELAY_OUTSIDE 
;---------------------------
DELAY_LOOP:
        MOVIA   197
        MOVAR   DELAY_INSIDE
DELAY_LOOP_INSIDE:
        CLRWDT
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        GOTO    $+1
        DECRSZ  DELAY_INSIDE,R
        GOTO    DELAY_LOOP_INSIDE
        DECRSZ  DELAY_OUTSIDE,R
        GOTO    DELAY_LOOP        
DELAY_2US:       
        CLRWDT
        NOP    
        NOP
        NOP	
        NOP	
        NOP	
        RETURN 
;***********************************************************
;函数名：WDT_Init
;***********************************************************
/****WDT overflow reset，have no wakeup funtions****；
则看门狗复位时间仅由烧录配置：288ms；512ms；766ms；1024ms；
*/
WDT_Init:
	CLRWDT
	BSR		STATUS,5	;RP0;转到bank1
	BCR		STATUS,6
	;OPTION_REG(BANK1)
	MOVIA	00CH		;0000 1100
	MOVAR	OPTION_REG	
			;Bit7：INT1EDG：外部中断1触发方式选择位（PB1）;0-falling edge, 1-rising edge
			;Bit6：INTEDG：外部中断触发方式选择位（PB0）	;0-falling edge, 1-rising edge
			

	;PCON(BANK1)(芯片控制寄存器)
	MOVIA	0A0H		;101- ----   	
	MOVAR	PCON		;Bit7：WDTE: WDT（看门狗定时器）使能位	;0-DIS, 1-EN
						;Bit5：LVREN: 低电压复位使能位			;0-DIS, 1-EN
						
	BCR		STATUS,5	;转到bank0
	BCR		STATUS,6
	RETURN














